All in one I.T. Tech software.

[NeoMatrix]

Re: All in one I.T. Tech software.

[Ver 1.1.2.57]
IT-Toolbox.exe software debug progress report.

There should be a version update released in a week or two.....

The pending release should fix some minor and major bugs in the current version.
There is a couple of new options an some other functions added in the newer version.

Hopefully time will permit........

[NeoMatrix]

Re: All in one I.T. Tech software.

Still here......[24/11/2016]

I hope to have an update version out by xmas time(2016), if not, then soon after.... I hope.....

I will require help from the usual software bug testers. It's a pain trying to continuously bug test all options...

I'd like some assistant from experienced I.T. guys to correct some of the operating system App side,and possibly clean up some of the network App issues. As with all operating systems, there is a few different ways to do the same job. It's handy to know if there is a better way to do the software job required. I like the K.I.S.S. method the best.

The software is designed for all Technical an IT personnel.


Apology for the delay....

.....

[NeoMatrix]

Re: All in one I.T. Tech software.

Yes ... same as before.... I have been plodding along in the man-cave.

I was about to release the lastest version ittbox.exe software yesterday when I stubbled across 3 more software bugs.

One bug halted the program. I have track down an fixed the darn illusive program halting bug.Two other minor bugs are still pending. For those interested, the minor bugs are associated with hanging pointers, which are an equal P.I.T.A to find. They are not critical, so I may release this version and fix them next round.

[NeoMatrix]

Re: All in one I.T. Tech software.

While I'm on the topic of bug fixes....? (29-4-17)
The below Del_Spooler.bat (ver 1.0) file had been post to a thread on the 27-04-2017.
I have found a spaces and line-feed error in Ver1.0 that is caused by copytechnet text formatting when ever a person cut and pastes blocks of text into a new post. I have repaired the line-feed error. I have modified the below Del_Spooler.bat batch file output text spacing, which compensates for Copytechnet text block formatting condition.
See insert version 1.1 below.

Purpose:
-----------------------------
Some office staff ,I.T. and Technicians have experienced a corrupt print out when sending files from their PC to a printer. The problem at times appears more so from pages printed off the internet. There are a number of causes for the corrupt print file problem. One of the causes may be a corrupt print job file sitting in the Spooler service print queue of the personal computer. To fix the corrupt print file on the PC you may need to manually force Windows sofware to clear the print queue. The inserted batch file below does that, in that it deletes all corrupt print files residing in the \windows\system32\spool\printers directory.

About Del_spooler batch file:
-------------------------------
On execution the Del_spooler.bat batch file will check for elevated administrator privileges, otherwise the batch file halts execution. The Del_spooler batch file must be run as an administrator to allow NET STOP SPOOLER and NET START SPOOLER to reset. If Del_spooler.bat passes the administrator test, the batch file then checks if there are any files in the \windows\system32\spool\printers directory. If no files are found, then the batch file exits. If Printer files are found in the \spool\printers directory, the batch file will display all files by Date,Time,Size,Owner and Filename. After displaying all files, Del_spooler will attempt to stop the windows print spooler services from receiving any new files into the\spool\Printers directory; by executing the NET STOP SPOOLER command.

After stopping the spooler services, the batch file will then attempt to (/Force) delete all files found in the Spool\Printers directory. After deleting all files from the \spool\printers directory, the batch file will attempt to restart the print spooler service with the NET START SPOOLER command.

After restarting the windows spooler service, the batch file will list any remaining files that where "not deleted" from the \spool\printer directory. If there are file(s) left over after deleting, those files may be hardware corrupt, or system protected files put there by undesirable activites. The user must delete those files manually.

Example Del_Spooler displayed output:
------------------------------------------------
(Apology for copytechnet ascii formatting)

======================================
****** WINDOWS XP -- WIN 10 **********
*** Clear Print Spooler directory. ***
* Author : NeoMatrix Date : 29-04-17 *
**** Website: www.copytechnet.com ****
==========================[Ver 1.1]===
--- Date ---- Time -------------- Size ---- Owner -------------- File Name ---
29/04/2017 12:39 PM ----------- 2,460 NT AUTHORITY\SYSTEM ------ 00002.SHD
29/04/2017 12:39 PM -------- 158,548 MyPC_APP\Sysop ------------- 00002.SPL

The Print Spooler service is stopping.
The Print Spooler service was stopped successfully.

All Spooler Print files deleted....

The Print Spooler service is starting.
The Print Spooler service was started successfully.

Press any key to continue . . .
-----------------------------------------------------


Cut and paste the inserted text below:
----------------------------------------
The batch file below is shown as a do-it-yourself text file to allay any concerns
about the transfer of viruses, or any other unwanted internet software code practices.

Using notepade.exe, cut and paste the below inserted batch file to a text file, and save the text file as Del_Spooler.bat.

Disclaimer :
----------------------
Use the following batch file as is at your own risk.

The below batch file has been tested on Win8.1

-----------8<--------------- insert ---------------------------------------------
@Echo off
@Echo ======================================
@Echo ****** WINDOWS XP -- WIN 10 **********
@Echo *** Clear Print Spooler directory. ***
@Echo * Author : NeoMatrix Date : 29-04-17 *
@Echo **** Website: www.copytechnet.com ****
@Echo ==========================[Ver 1.1]===
@Rem Operating System: Microsoft Windows only.
@Rem Must be run as Windows administrator.
@Rem Feel free to modify this batch file however.
@Echo.

:Initialise
@Setlocal
@Set SpoolerDir="%comspec:cmd.exe=%spool\printers"

:Start
@>nul 2>nul dir /a-d "%SpoolerDir%\*" && (goto CheckPrivileges)
@Echo No file(s) found in Spooler Print directory :
@Echo %SpoolerDir%
@Echo.
@goto Halt

:CheckPrivileges
@Rem Check user has elevated admin privileges by forcing condition test.
@NET FILE 1>NUL 2>NUL
@if '%errorlevel%'=='0' goto AllOk
@Echo Batch file must be run as Administrator
@Echo to allow Spooler Service to Reset.
@Echo.
@goto Halt

:AllOk
@Rem @Echo Deleting all Print Files in :
@Rem @Echo %SpoolerDir%
@Rem Remove unwanted DIR headings.
@echo --- Date ---- Time -------------- Size ---- Owner -------------- File Name ---
@FOR /f "tokens=*" %%D IN ('dir /q /a-d %spoolerdir%\*.* ^| find "/"') DO echo %%D
@Echo.

:MainExecution
@Net stop spooler
@Del /F /Q %SpoolerDir%\*.*
@Echo All Spooler Print files deleted....
@Echo.
@Net start spooler
@Echo.

:Remaining
@Rem Show if any corrupt files still remaining in Spooler directory.
@>nul 2>nul dir /a-d "%SpoolerDir%\*" || (goto Halt)
@Echo Files Still Remaining in Spooler Directory :
@Echo -------------------------------------------
@Dir %SpoolerDir% /b
@Echo.

:Halt
@EndLocal
@pause
-----------8<--------------- End ------------------------------------------------

[ZOOTECH]

Re: All in one I.T. Tech software.

Mat, I hope you are spending as much time with your wife as you are with this honorable project!

[NeoMatrix]

Re: All in one I.T. Tech software.

Mat, I hope you are spending as much time with your wife as you are with this honorable project!

Ouch... so you noticed that too...

Hmm... no rest for the wicked as they saying goes.

[ZOOTECH]

Re: All in one I.T. Tech software.

Ouch... so you noticed that too...

Hmm... no rest for the wicked as they saying goes.

Get some rest, hopefully, with your loved one. It's always better that way!!!

[NeoMatrix]

Re: All in one I.T. Tech software.

Just spring cleaning... [13-08-18]
I've post the below LDAP ad.bat (ver1.3) below for keepsake before I delete the LDAP folder off my HDD.
Some other people might find a use for it....

For those that don't know the LDAP batch file topic was raised in the following post:
hhttp://www.copytechnet.com/forums/konica-minolta/130117-populating-address-book-post607124.html#post607124
Populating the address book

Feel free to modify the below batch file to suit your requirements.

Oh! and you'll require copy of ADFIND.EXE. You can download a copy of "Adfind.exe" from this URL:
hhttp://joeware.net/freetools/tools/adfind/index.htm
AdFind

The below version fix's and output bug from ad.bat ver 1.2, and has been optimised for a lot faster execution.

------------------------8<--------------------------------------------------------------------------------------------------------

echo off
setlocal ENABLEDELAYEDEXPANSION ENABLEEXTENSIONS
cls
echo ************* LDAP Server Query. ********************
echo This batch file Querys a public internet LDAP server.
echo Output is limited to 50 lines of formatted text.
echo This is a totally random LDAP filter demonstration.
echo Author:Neomatrix, www.copytechnet.com
echo ***********************************[Ver 1.3]*********
echo.
echo Running... please wait....

rem -------------------- Main --------------
rem Debian host is anonymous login, no password required.
set LDAP_Server=db.debian.org:389
set datafile="_ldapdata.txt"
set csvfile="_outfile.txt"
set "T= "
set "Bar="
for /L %%i in (1,1,70) do set "Bar=!Bar!="
rem set maxlines high value to output all lines.
set /a maxlines=50

rem *** Critical matching search and output fields here.***
rem *** Add more matching fields here as required. ***
rem *** Must update ---filter--- procedure to same. ***
set "RS=dn:"
set /a matching=4
set "f1=>cn:"
set "f2=>sn:"
set "f3=>labeledURI:"
set "f4=>keyFingerPrint:"
set fields="!RS! !f1! !f2! !f3! !f4!"

rem *** main ****
call :Init !LDAP_Server! !datafile! !fields!
call :Header !csvfile!
call :Body !datafile! !csvfile!
call :Footer !csvfile!
call :CRT_Display !csvfile!
goto End


rem ----------------- Init -----------------
:Init LDAP_Server datafile fields
set host=-h %1 -simple -up
rem set sw=-list -s one -soao
set "sw="
set params=-b ou=users,dc=debian,dc=org
rem **Filter LDAP server data here with user fields.**
(adfind %host% %sw% %params% | findstr /i /p /b %3) > %2
if %~z2==0 (
echo No matching filter records found...
set NoRecords=1
exit /b
)
echo LDAP server query done...
exit /b

rem ---------------- Header ----------------
:Header outfile
echo !Bar! > %1
echo First!T!Last!T!!T!PGP Key!T!!T!URL >>%1
echo !Bar! >> %1
exit /b

rem ------------------ Filter -------------
:Body datafile csvfile
set /a max=0
set /a block=0
set /a sameblock=1

rem for /f "tokens=1* delims=:" %%i in ('findstr /i /p !fields! %~1') do (
for /f "tokens=1* delims=:" %%i in (%~1) do (
set id=%%i:
set value=%%j
if "!id!"=="!RS!" set /a block=!block!+1

if !block!==!sameblock! (
rem *** filter values from datafile ***
rem add more search and output fields here.
if "!id!"=="!f1!" set cname=!value!
if "!id!"=="!f2!" set sname=!value!
if "!id!"=="!f3!" set aUrl=!value!
if "!id!"=="!f4!" set Pgp=!value!
set /a cnt=!cnt!+1

) else (

rem *** Output 1-4 matching fields above. ***
if !cnt! GEQ !matching! (
echo !cname!,!sname!,!Pgp:~0,16!,!aUrl!>> %2

rem **limit max lines output**
set /a max=!max!+1
if !max!==!maxlines! exit /b

rem ** must clear if "matching" less than fields count **
set "cname="
set "sname="
set "aUrl="
set "Pgp="
)
set /a sameblock=!block!
set /a cnt=0
))
exit /b

rem ---------------- Footer ----------------
:Footer outfile
echo !Bar! >> %1
echo Searched Users: !block! Filter matched :!max! Truncated at:!maxlines! >> %1
exit /b

rem ---------------- CRT Display ----------------
:CRT_Display outfile
if DEFINED NoRecords exit /b
type %1
exit /b

:End
endlocal
echo hit any key to quit...
> nul timeout /t 15



------------------------8<--------------------------------------------------------------------------------------------------------

[NeoMatrix]

Re: All in one I.T. Tech software.

Trying to keep all the relevant topics in one place, so I can find them a bit easier... [16-08-18]

The following topic comes from the below forum.
hhttp://www.copytechnet.com/forums/connectivity/129798-little-fyi-those-scan-smb-issues-smb1-disabled-post609138.html#post609138

A little fyi for those with scan to smb issues with smb1 disabled

Scan to FTP using a local in-house NAS device or private cloud.

-----------------------------8<------------------------------------------------------------
You don't require any additional FTP server software running on any PC or Server.

FTP Plug-n-Play for DIY home/small office Networks:

1. Plug 1GB - 2 Terrabyte USB/FLASH/HDD/SSD into any PC. Create individual customer scan folder/directories for all PC's on the network onto this USB stick or HDD. This will be come our NAS (Network Address/Adapter Share)
USB/HDD Create Folder example:
|_Bill
|_Fred
|_Mary
|_Jane

2. Plug in the above NAS into the local network "Modem/Router" or "Switch".

3. You will need to enter the NAS Router or switch configuration WIM (eg.http://10.1.1.254) and setup customized names,passwords and individual directories. These are the same directories you created in step 1. on the USB/HDD. Look for the "Set up Share" menu tab while inside the Router WIM.
Share setup Example:
User/Share name : Mary
Password : -accounts-123-
[x] Use directory :Mary
[x] read/write access

4.Configure all your customers MFD's or Scanners to "FTP Scan" to the same multiple customised NAS directories above.
Ricoh MFD address book setup :
FTP[x]
user :Mary
password :-accounts-123-
scan to folder:\\10.1.1.254\Mary\

5.On all PC's, run windows "File Explorer".
Right click on: Computer | Map Network Drive | enter \\NAS-IP<eg.10.1.1.254>\NAS-User-Id<eg Mary>\ | [Z] Drive | [x] Reconnect at logon| <enter>


DIY scan to FTP --as straight forward as it can be.

NB. FTP is not totally secure, but its a step up from SMBv1-2.

HTH




-----------------------------8<------------------------------------------------------------

[NeoMatrix]

Re: All in one I.T. Tech software.

An LDAP topic reference by TheOwl....

htttp://www.copytechnet.com/forums/connectivity/68472-ldap-dummies.html#post307313

http://www.copytechnet.com/forums/connectivity/68472-ldap-dummies.html#post307313

[NeoMatrix]

Re: All in one I.T. Tech software.

Copy an paste to this forum...



************************************************** ************************


08-16-2016, 02:59 PM

[Firmware Unzip23.bat version 2.3]

Extracts multiple Ricoh or Kyocera firmware to SD-Card or HDD

Requirement:
7-Zip.exe source : 7-Zip download | SourceForge.net



General update to version 2.2
For those people who have request the use of this batch file.
The following is a version update from 2.1 to 2.3
The current batch file is used the same as all other versions.

In version 2.3 there have been some minor error handling changes, along with additional output for user feed back;otherwise the *.bat file is just the same.

If you cut and paste the below snip text to a *.bat, file you will need to repair the menu spacing * * lines in
the menu block. CTN automatically removes those duplicate spaces causing the * * indentation.
You must also place any line wrapped text back to the previous single line.



---------------------------------8<------------Cut an paste to any *.bat file ----------------------------------------------
@Echo off
@CLS
@REM This batch file is for extracting multiple firmware zip files onto an SD/CF card or hardrive
@REM directory.
@REM Copyright(C) 2010 Neomatrix Updated : 16/08/2016 (dd/mm/yy)
@REM Version 2.3
@REM [Ver2.3] Minor error handling modifications. Add more visual feed back.
@REM Important : Requires 7-ZIP.exe archive utility. This can be downloaded off the Internet.
@REM Usage : 7ZA.EXE e -i!*.fwu -y firmware.zip
@REM 7ZA.EXE e = extract -i = includefiles !*.fwu = !filespec -o = Ouput direct -y = yes all
@REM prompts Firmware.zip archive.
@REM 7ZA full file and path name must exist : Example : Set Zip7path="c:\program files (x86)
@REM \7za\7ZA.EXE"
@REM Must use quotation marks if spaces are used in above path name.
@REM

@REM HOW TO USE :
@REM To uses this file, simple copy the unzip23.bat batch file into the same firmware directory
@REM and double click.
@REM When run with out any paramaters, the program will default to the "Homedrive\romdata"
@REM directory of the operating system main drive.
@REM To force extraction to a SD/CF card, run the upzip23.bat file from a command prompt with
@REM the drive letter of the SD/CF card. Example unzip23 h:
@REM Please feel free add your own improvement ideas and/or to share this batch file with
@Rem whomever.

@Rem Important set the default 7za.exe path here
@REM Set Zip7path="C:\Program Files (x86)\7za\7ZA.EXE"
@Set Zip7path="%ProgramFiles(x86)%\7za\7ZA.EXE"
@REM Echo %Zip7path%
IF NOT EXIST %Zip7path% GOTO ERROR:

@Echo.
@Echo ****************[ RICOH - KYOCERA ]******************
@Echo * EXTRACT FIRMWARE *
@Echo * Unzip Batch Mode *
@Echo ********************************* Copytechnet.com ***
@Echo * *
@Echo * Usage : unzip23 [drive:\path\] *
@Echo * Example : unzip23 h: {defaults h:\romdata} *
@Echo * Copy unzip23.bat to the firmware source directory.*
@Echo * Unzip23 extracts *.zip and *.exe archive formats, *
@Echo * an exports the *.fwu,*.rfu and *.bin files only. *
@Echo * *
@Echo ***************************************[Ver 2.3]*****
@Echo.

@Set drive=%1
@Set direct=%1\romdata
@REM change default drive here if param line empty.
@IF "%1x"=="x" Set drive=%HOMEDRIVE%
@IF "%1x"=="x" Set direct=%HOMEDRIVE%\romdata
@Echo Extracting to :%direct%
@Echo Press Ctrl-C at any time to terminate batch process.
@Echo.
@pause
@REM Allow Unzip.Bat to run 5 times while saving any existing romdata directory files.
@REM Each time this batch file is run all previous romdata_? folders are renamed letter incremented.
@REM Renaming prevents overwritting previous firmware by mistake. Delete the last Romdata_E
@REM folder off the list.
@REM Always Delete 5th backup directory Romdata_E and sub directories regardless.
@IF NOT EXIST %drive%\Romdata_E GOTO AD:
@Echo Deleted directory %drive%\Romdata_E
@RD %drive%\Romdata_E /Q /S

:AD
@IF NOT EXIST %drive%\Romdata_D GOTO AC:
@RENAME %drive%\Romdata_D Romdata_E
@Echo %drive%\Romdata_D Rename to %drive%\Romdata_E

:AC
@IF NOT EXIST %drive%\Romdata_C GOTO AB:
@RENAME %drive%\Romdata_C Romdata_D
@Echo %drive%\Romdata_C Rename to %drive%\Romdata_D

:AB
@IF NOT EXIST %drive%\Romdata_B GOTO AA:
@RENAME %drive%\Romdata_B Romdata_C
@Echo %drive%\Romdata_B Rename to %drive%\Romdata_C
:AA
@IF NOT EXIST %drive%\Romdata_A GOTO AR:
@RENAME %drive%\Romdata_A Romdata_B
@Echo %drive%\Romdata_A Rename to %drive%\Romdata_B
:AR
@IF NOT EXIST %drive%\Romdata GOTO MakeDirect:
@RENAME %drive%\Romdata Romdata_A
@Echo %drive%\Romdata Rename to %drive%\Romdata_A

:MakeDirect
@Echo.
@REM Make the directory in the SD/CF card or H/D path.
@REM MakeDir Will default with an error echo if directory already exists.
@IF NOT EXIST %direct% md %direct%
@REM %%f = file variable to use. Add your extract file specs inside the brackets.
@Echo ****** 7-Zip is Extracting Multiple Firmware ********
@FOR %%f in (*.zip;*.exe) do %Zip7path% e -i!*.fwu -i!*.bin -i!*.rfu -o%direct% -y %%f
@GOTO END:

:Error
@Echo ERROR : User input parameters are invalid check :
@Echo [drive\path\romdata] : %1
@Echo Check 7za.exe is in the correct directory.
@GOTO EOF:

:End
@Echo.
@Echo ************************************************** ********
@Echo All "*.fwu, *.rfu or *.bin" files have been extracted to :
@Echo %direct%
@Echo ************************************************** ********
@IF NOT EXIST %1\Romdata_B GOTO EOF
@Echo Existing romdata folder(s) have been renamed. See
@Echo the start of this window for further details.
@Echo ************************************************** ********
@Echo.

:EOF
@pause

---------------------------------8<----------------------------------------------------------------------------

[NeoMatrix]

Re: All in one I.T. Tech software.

A batch file to reset any Hard Disk Drive back to factory uninitialized configuration.

Cut and paste from below forum.

hhttp://www.copytechnet.com/forums/kyocera-mita-copystar/134721-hdd-drives.html#post715183

http://www.copytechnet.com/forums/kyocera-mita-copystar/134721-hdd-drives.html#post715183

[klimbo123]

Re: All in one I.T. Tech software.

Trying to keep all the relevant topics in one place, so I can find them a bit easier... [16-08-18]

The following topic comes from the below forum.
hhttp://www.copytechnet.com/forums/connectivity/129798-little-fyi-those-scan-smb-issues-smb1-disabled-post609138.html#post609138

A little fyi for those with scan to smb issues with smb1 disabled

Scan to FTP using a local in-house NAS device or private cloud.

-----------------------------8<------------------------------------------------------------
You don't require any additional FTP server software running on any PC or Server.

FTP Plug-n-Play for DIY home/small office Networks:

1. Plug 1GB - 2 Terrabyte USB/FLASH/HDD/SSD into any PC. Create individual customer scan folder/directories for all PC's on the network onto this USB stick or HDD. This will be come our NAS (Network Address/Adapter Share)
USB/HDD Create Folder example:
|_Bill
|_Fred
|_Mary
|_Jane

2. Plug in the above NAS into the local network "Modem/Router" or "Switch".

3. You will need to enter the NAS Router or switch configuration WIM (eg.http://10.1.1.254) and setup customized names,passwords and individual directories. These are the same directories you created in step 1. on the USB/HDD. Look for the "Set up Share" menu tab while inside the Router WIM.
Share setup Example:
User/Share name : Mary
Password : -accounts-123-
[x] Use directory :Mary
[x] read/write access

4.Configure all your customers MFD's or Scanners to "FTP Scan" to the same multiple customised NAS directories above.
Ricoh MFD address book setup :
FTP[x]
user :Mary
password :-accounts-123-
scan to folder:\\10.1.1.254\Mary\

5.On all PC's, run windows "File Explorer".
Right click on: Computer | Map Network Drive | enter \\NAS-IP<eg.10.1.1.254>\NAS-User-Id<eg Mary>\ | [Z] Drive | [x] Reconnect at logon| <enter>


DIY scan to FTP --as straight forward as it can be.

NB. FTP is not totally secure, but its a step up from SMBv1-2.

HTH




-----------------------------8<------------------------------------------------------------

thank you for this good explication
best regards bro

[klimbo123]

Re: All in one I.T. Tech software.

Trying to keep all the relevant topics in one place, so I can find them a bit easier... [16-08-18]

The following topic comes from the below forum.
hhttp://www.copytechnet.com/forums/connectivity/129798-little-fyi-those-scan-smb-issues-smb1-disabled-post609138.html#post609138


Scan to FTP using a local in-house NAS device or private cloud.

-----------------------------8<------------------------------------------------------------
You don't require any additional FTP server software running on any PC or Server.

FTP Plug-n-Play for DIY home/small office Networks:

1. Plug 1GB - 2 Terrabyte USB/FLASH/HDD/SSD into any PC. Create individual customer scan folder/directories for all PC's on the network onto this USB stick or HDD. This will be come our NAS (Network Address/Adapter Share)
USB/HDD Create Folder example:
|_Bill
|_Fred
|_Mary
|_Jane

2. Plug in the above NAS into the local network "Modem/Router" or "Switch".

3. You will need to enter the NAS Router or switch configuration WIM and setup customized names,passwords and individual directories. These are the same directories you created in step 1. on the USB/HDD. Look for the "Set up Share" menu tab while inside the Router WIM.
Share setup Example:
User/Share name : Mary
Password : -accounts-123-
[x] Use directory :Mary
[x] read/write access

4.Configure all your customers MFD's or Scanners to "FTP Scan" to the same multiple customised NAS directories above.
Ricoh MFD address book setup :
FTP[x]
user :Mary
password :-accounts-123-
scan to folder:\\10.1.1.254\Mary\

5.On all PC's, run windows "File Explorer".
Right click on: Computer | Map Network Drive | enter \\NAS-IP<eg.10.1.1.254>\NAS-User-Id<eg Mary>\ | [Z] Drive | [x] Reconnect at logon| <enter>


DIY scan to FTP --as straight forward as it can be Bluestacks Kodi Lucky Patcher

NB. FTP is not totally secure, but its a step up from SMBv1-2.

HTH




-----------------------------8<------------------------------------------------------------

thank you for this good explication
best regards bro

[NeoMatrix]

Re: All in one I.T. Tech software.

A simple batch file to test for duplicate , unauthorised or conflicting IP addresses on any network.
Cut an paste the below batch file to any text file and name the file XPing.bat...

You may need to run the batch file from administrator mode for the windows Ping.exe command.

Pipe the Xping.bat output to CMD window text file and check against your normal network white list of
authorised IP addresses. Unknown IP addresses means hacker unauthorized access.

Pipe example:
xping 10.1.1.1 255 > testIp.txt

You must allow a rule for the ICMP command in your firewall if want to access the WAN ping results.

----------------------8<------------------------------------------------------------------------------------

echo off
setlocal ENABLEDELAYEDEXPANSION ENABLEEXTENSIONS
cls
echo **********************[ Multi Ping ]******************************
echo Ping multiple IP addresses for duplicate IP errors.
echo Test for unauthorised network IP addresses.
echo Useage:
echo Input parameter start IP Address and end IP range.
echo Example : Xping.bat 10.1.1.0 255
echo Author : NeoMatrix wwww.copytechnet.com
echo *************************************************[Ver 1.0] *******
echo.

if "%2x"=="x" goto Error
if "%1x"=="x" goto Error


rem -------- Main Flow ----------

Call :StartAddr %1 %2 Domain Fault

If DEFINED Fault goto Error

Call :FindIp %Domain% %2

goto End


rem ------------- Find IP -----------
:FindIp Domain Range
rem Change the ping return wait time here,in millisec.
Set Wait=10
Set Passive=10
Set Params=-a -w %Wait% -n 1
Set "Modu="

for /L %%I in (1,1,%2) do (


set /a Modu=%%I %% %Passive%
set Addr=%1.%%I

(ping %Params% !Addr! | findstr /C:"Received = 1" ) > nul && echo Active IP : !Addr! || (

if !Modu!==0 echo Passive to: ... %1.%%I
if %%L==%2 exit /b
))

exit /b


rem ----------- Domain Range ---------

:StartAddr InDomain Range Domain Fault
Set "Fault="

for /F "tokens=1-4* delims=." %%A in ("%1") do (

if "%%Dx"=="x" Set %4=1
if %%D GTR 255 Set %4=1

Set %3=%%A.%%B.%%C
)

Echo Press Ctrl_C to cancel batch file...
echo Wait...
echo.
Echo ---------------------------------------
Echo Start : %1, End : %Domain%.%2
Echo ---------------------------------------

exit /B


rem ---------- Errors ------------
:Error
Echo Parameter Error: enter start IP address and/or end IP-Range.
Echo Example: Xping.bat 10.1.1.0 255
Echo Ping command requires activation from Administrator mode.
echo Change the reply wait time milliseconds to a higher value.

:End
endlocal

echo ---------------------------------------
echo.
echo Hit any key to exit...
> nul timeout /t 5



----------------------8<------------------------------------------------------------------------------------